Coding4ever’s Blog

Just coding… coding… and coding… because coding should be fun :)

Belajar Winsock Bagian 2 - Membuat Aplikasi Chat Sederhana 1:1

| Comments

Setelah memahami properties-properties dasar yang harus disetting untuk membuat aplikasi sederhana menggunakan winsock, pada artikel ke 2 dari 5 seri belajar winsock ini kita akan membuat aplikasi chat sederhana dengan pola 1:1 atau dengan istilah lainnya single connection.

Membuat aplikasi chatting seperti MSN Messenger atau Yahoo Messenger sebenarnya mudah (tapi tidak termasuk saya ya :D) dan kita sudah mempelajari bagaimana membuat koneksi sederhana menggunakan winsock, selanjutnya kita tinggal mengirimkan data menggunakan method .SendData dan menghandle data yang diterima melalui event Winsock_DataArrival.

Contoh penggunaan method SendData :

1
2
3
4
5
6
Private Sub cmdSend_Click()
    With Winsock1
        .SendData "Belajar Winsock Bagian 2"
    End With
    DoEvents
End Sub

Pemanggilan fungsi DoEvents untuk memberikan jeda waktu untuk menyelesaikan pengiriman data.

Kode untuk menghandle data yang masuk juga sangat sederhana. Winsock menerima data dan menyimpannya di dalam buffer. Untuk memanggil data ini, kita tinggal memanggil method .GetData dan ingat kita tidak bisa memanggil method ini setiap waktu karena setelah itu buffer otomatis dikosongkan. Jadi waktu yang tepat untuk memanggil method ini adalah pada saat event Winsock_DataArrival dijalankan.

Contoh penggunaan method GetData :

1
2
3
4
5
6
Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
    Dim strData As String

    Call Winsock1.GetData(strData)
    MsgBox strData
End Sub

Oke, sampai disini kita sudah mengetahui dasar-dasar untuk membuat aplikasi chat sederhana dan untuk mendemokan ini kita akan membutuhkan 2 program kita sebut saja klien dan server. Adapun persiapan untuk aplikasi server/klien :

  1. Objek Winsock

  2. Label

  3. 2 TextBox

  4. CommandButton

Source code lengkap aplikasi server :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Option Explicit

Private Sub cmdSend_Click()
    Winsock1.SendData txtChat.Text
    DoEvents

    txtMain.Text = txtMain.Text & vbCrLf & txtChat.Text
    txtChat.Text = ""
End Sub

Private Sub Form_Load()
    Winsock1.LocalPort = 11111
    Winsock1.Listen
End Sub

Private Sub Winsock1_ConnectionRequest(ByVal requestID As Long)
    'reset the socket, and accept the new connection
    Winsock1.Close
    Winsock1.Accept requestID
End Sub

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
    Dim strData As String

    'get the data and display it in the textbox
    Winsock1.GetData strData
    txtMain.Text = txtMain.Text & vbCrLf & strData
    txtMain.SelStart = Len(txtMain.Text)
End Sub

Aplikasi server tinggal duduk maniz :D dan menunggu koneksi yang masuk.

Source code lengkap aplikasi klien :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Option Explicit

Private Sub Form_Load()
    'set up the Winsock1 to connect to the local computer
    Winsock1.RemoteHost = "127.0.0.1"
    Winsock1.RemotePort = 11111
    Winsock1.Connect
End Sub

Private Sub cmdSend_Click()
    'send the data thats in the text box and
    'clear it to prepare for the next chat message
    Winsock1.SendData txtChat.Text
    DoEvents

    txtMain.Text = txtMain.Text & vbCrLf & txtChat.Text
    txtChat.Text = ""
End Sub

Private Sub Winsock1_Connect()
    'we are connected!
    MsgBox "Connected"
End Sub

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
    Dim strData As String

    ' get the data from the socket
    Winsock1.GetData strData
    ' display it in the textbox
    txtMain.Text = txtMain.Text & vbCrLf & strData
    ' scroll the box down
    txtMain.SelStart = Len(txtMain.Text)
End Sub

Private Sub Winsock1_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
    ' an error has occured somewhere, so let the user know
    MsgBox "Error: " & Description
    ' close the socket, ready to go again
    Winsock1.Close
End Sub

Sample program bisa didownload disini dan artikel berikutnya insya Alloh dengan judul Belajar Winsock bagian 3 – Multiple Connection segera menyusul.

Selamat mencoba :)

visual basic, winsock

Tentang Penulis

Software developer yang fokus mengembangkan aplikasi di atas platform .NET (Desktop, ASP.NET MVC, Web Service) dan Android. Senang mempelajari teknologi baru terutama di bidang OOP, Design Pattern, ORM, Database dan Continuous Integration & Deployment.
Saat ini bekerja sebagai staf IT di salah satu PTS di Yogyakarta sebagai senior software developer. Di waktu luang insya Alloh akan terus berbagi pengalaman di blog ini :)

« Belajar Winsock bagian 1 - Intro Belajar Winsock bagian 3 – Multiple Connection »

Comments