Membuat paket instalasi vb + mysql dengan NSIS

Posted by Kamarudin • 7 minute read • Comments

Melengkapi tulisan saya Membuat paket instalasi vb + mysql dengan inno setup kali ini kita akan membuatnya menggunakan NSIS.

NSIS adalah salah satu tool gratis dan open source untuk membuat paket instalasi. Oke sebelum kita melangkah lebih jauh, berikut adalah hal-hal yang perlu kita persiapkan :

  1. NSIS
  2. MySQL versi noninstall disesuaikan dengan versi MySQL yang terinstall di komputer Anda
  3. Connector ODBC yang sudah terinstall biasanya ada di C:\Program Files\MySQL\Connector ODBC 5.1
  4. Database yang sudah di backup/dump
  5. Untuk editor, bagi Anda yang buta warna cukup pake notepad :grin:, saya sendiri menggunakan notepad++ atau kalo pengen lebih nyaman bisa menggunakan eclipse kemudian download plug-in NSIS

Memang kalo dilihat dari segi skrip,  Inno Setup lebih simple dibandingkan NSIS tetapi setelah saya bandingkan hasil paket instalasi NSIS lebih kecil dibandingkan Inno Setup.

Skrip Inno Setup dan NSIS sama-sama dikelompokkan dalam section-section bedanya kalo Inno Setup untuk nama sectionnya sudah fix (misal Setup, Tasks, Files de el el) sedangkan NSIS untuk nama sectionnya bebas dan tentunya dalam penamaan section di NSIS disesuaikan dengan isinya (misal Install MySQL 5).

Salah satu bagian penting dari skrip NSIS yang kita bahas disini adalah skrip yang digunakan untuk membuat service MySQL, mendaftarkan driver MySQL Connector ODBC dan melakukan proses undump skrip databse (.sql).

Saya ambil contoh untuk membuat service MySQL tentunya dilihat dari versi windows yang terinstall kalo keluarga Win9x jelas tidak bisa karena belum mendukung pembuatan service, oleh karena itu sebelum menjalankan perintah membuat service akan dilakukan pengecekan versi windows terlebih dulu.

Nah disini akan terlihat jelas perbedaan skrip Inno Setup dan NSIS dimana untuk melakukan ini inno setup cukup menambahkan flag MinVersion, misal :

[Run]
;mysqld --install MySQL
Filename: "{app}\mysql\bin\mysqld.exe"; Parameters: "install ""MySQL"""; StatusMsg: "Sedang menginstall service MySQL ..."; Flags: runhidden; MinVersion: 0,5.01.2600sp2; Tasks: installmysql

Sedangkan untuk NSIS kita perlu mendownload Version plug-in terlebih dulu dan mengekstraknya kemudiakan mengcopykan file version.dll ke folder instalasi NSIS\Plugins, walaupun sebenarnya kita bisa membuat fungsi sendiri di NSIS untuk mengecek versi windows yang terinstall.

Contoh skrip NSIS untuk mengecek versi windows dan menginstall service MySQL :

Section "Install MySQL 5"
	Version::IsWindowsXP

	Pop $0 ;nilai var $0 akan bersisi 1 jika windows XP selain itu 0
	StrCmp $0 "1" ItIsWindowsXP ItIsNotWindowsXP ;StrCmp sama seperti fungsi IIF di VB

	ItIsWindowsXP:
	Goto installservice

	ItIsNotWindowsXP:
	Goto done

	installservice:
		DetailPrint "Sedang menginstall service MySQL ..."
		ExecWait '"$MYSQL_DIR\bin\mysqld.exe" install "MySQL"'

	done:
		;do nothing
SectionEnd

Gimana lumayan beda kan? :blush:

Khusus untuk file-file Runtime VB memerlukan penanganan khusus dan untuk memudahkan Anda mencoba sample skrip ini download terlebih dahulu file Runtime VB disini dan jangan lupa diekstrak.

Persiapan terakhir untuk struktur folder saya buat seperti berikut :

Dan saya tidak akan menjelaskan fungsi-fungsi/perintah yang digunakan dalam skrip NSIS karena sudah saya sisipkan komentar di sample skrip instalasi NSIS.

Jika masih kesulitan Anda bisa langsung membaca manual NSIS yang penjelasannya sudah sangat lengkap.

Berikut contoh skrip instalasi lengkap menggunakan NSIS :

;Skrip instalasi by k4m4r82
;http://coding4ever.wordpress.com

!include VB6RunTime.nsh

;deklarasi konstanta
;format pemanggilan ${NAMA_KONSTANTA}
!define APP_NAME "Sistem Pembelian Bahan Baku PT. ALBASI"
!define APP_PUBLISHER "K4m4r82's Laboratory"
!define APP_VERSION "2.0.50"

BrandingText /TRIMCENTER "-- ${APP_PUBLISHER} --"
Name "${APP_NAME} ${APP_VERSION}"
Caption "${APP_NAME} ${APP_VERSION}"

CompletedText "Instalasi sudah selesai"

Icon "setup.ico"
LoadLanguageFile "${NSISDIR}\Contrib\Language files\Indonesian.nlf"
OutFile "output\DemoSetupNSIS.exe"
ShowInstDetails show
ShowUninstDetails show
WindowIcon on
XPStyle on

;informasi default folder instalasi
InstallDir "$PROGRAMFILES\SPBB"

;informasi folder instalasi disimpan disini
;informasi ini akan memudahkan kita untuk membuat program update
InstallDirRegKey HKCU "Software\PT ALBASI\SPBB" "InstallDir"

VIAddVersionKey /LANG=${LANG_INDONESIAN} "ProductName" "${APP_NAME}"
VIAddVersionKey /LANG=${LANG_INDONESIAN} "Comments" ""
VIAddVersionKey /LANG=${LANG_INDONESIAN} "CompanyName" "${APP_PUBLISHER}"
VIAddVersionKey /LANG=${LANG_INDONESIAN} "LegalTrademarks" "${APP_NAME} is a trademark of ${APP_PUBLISHER}"
VIAddVersionKey /LANG=${LANG_INDONESIAN} "LegalCopyright" "Copyright © 2009. ${APP_PUBLISHER}"
VIAddVersionKey /LANG=${LANG_INDONESIAN} "FileDescription" "${APP_NAME}"
VIAddVersionKey /LANG=${LANG_INDONESIAN} "FileVersion" "2.0.0.50"
VIProductVersion "2.0.0.50"

RequestExecutionLevel admin

AddBrandingImage left 150|234
Page custom BrandingImage
Page components
Page directory
Page instfiles

UninstPage custom un.BrandingImage
UninstPage uninstConfirm
UninstPage instfiles

;deklarsi variabel
;format pemanggilan $NAMA_VARIABEL ingat ada sedikit perbedaan dg konstanta
Var MainDir
Var MySQLDir
Var AlreadyInstalled

;section yang diawali karakter -, pilihannya tidak ditampilkan
Section "-Inisialisasi Variabel"
    StrCpy $MainDir $INSTDIR
	StrCpy $MySQLDir $MainDir\mysql
SectionEnd

Section "-Visual Basic Runtime"
	;download file Visual Basic Runtime di: http://nsis.sourceforge.net/vb6runtime.zip
	IfFileExists "$MainDir\Albasi.exe" 0 new_installation
		StrCpy $AlreadyInstalled 1

	new_installation:
		!insertmacro VB6RunTimeInstall "dll&ocx\vb6runtime" $AlreadyInstalled
SectionEnd

Section "-My Application Runtime"
	SetOutPath $MainDir
        File "main\Albasi.exe.manifest"
	File "main\Albasi.exe"

	SetOutPath $SYSDIR

	File "dll&ocx\LVbuttons.OCX"
	RegDLL "$SYSDIR\LVbuttons.ocx"

	File "dll&ocx\MSMASK32.OCX"
	RegDLL "$SYSDIR\MSMASK32.ocx"

	File "dll&ocx\cTreeOpt6.ocx"
	RegDLL "$SYSDIR\cTreeOpt6.ocx"

	File "dll&ocx\Comdlg32.ocx"
	RegDLL "$SYSDIR\Comdlg32.ocx"

	File "dll&ocx\vbalDTab6.ocx"
	RegDLL "$SYSDIR\vbalDTab6.ocx"

	File "dll&ocx\vbalExpBar6.ocx"
	RegDLL "$SYSDIR\vbalExpBar6.ocx"

	File "dll&ocx\MSCOMCTL.OCX"
	RegDLL "$SYSDIR\MSCOMCTL.ocx"

	File "dll&ocx\vbalIml6.ocx"
	RegDLL "$SYSDIR\vbalIml6.ocx"

	File "dll&ocx\cPopMenu6.ocx"
	RegDLL "$SYSDIR\cPopMenu6.ocx"

	File "dll&ocx\cNewMenu6.dll"
	RegDLL "$SYSDIR\cNewMenu6.DLL"

	File "dll&ocx\scrrun.dll"
	RegDLL "$SYSDIR\scrrun.DLL"

	File "dll&ocx\vbalMDITabs6.dll"
	RegDLL "$SYSDIR\vbalMDITabs6.DLL"

	File "dll&ocx\SSubTmr6.dll"
	RegDLL "$SYSDIR\SSubTmr6.DLL"

	File "dll&ocx\msado21.tlb"
	RegDLL "$SYSDIR\msado21.tlb"
SectionEnd

; param /e -> expand
SectionGroup /e "Komponen Server"
	Section "Install MySQL 5"
		; param /r -> recursive
		SetOutPath $MySQLDir\bin
		File /r "mysql-5.1.36-win32\bin\*.*"

		SetOutPath $MySQLDir\Docs
		File /r "mysql-5.1.36-win32\Docs\*.*"

		SetOutPath $MySQLDir\lib
		File /r "mysql-5.1.36-win32\lib\*.*"

		SetOutPath $MySQLDir\share
		File /r "mysql-5.1.36-win32\share\*.*"

		SetOutPath $MySQLDir\data
		File /r "mysql-5.1.36-win32\data\*.*"

		SetOutPath $MySQLDir
		File "mysql-5.1.36-win32\*.*"

		;informasi lokasi instalasi mysql
		WriteINIStr $MySQLDir\my.ini "mysqld" "basedir" $MySQLDir
		WriteINIStr $MySQLDir\my.ini "mysqld" "datadir" $MySQLDir\data

		;proses membuat dan menjalankan service mysql, cek versi windows terlebih dulu
		;untuk contoh disini baru di tes untuk windows xp sp2
		Version::IsWindowsXP

		Pop $0 ;nilai var $0 akan bersisi 1 jika windows XP selain itu 0
		StrCmp $0 "1" ItIsWindowsXP ItIsNotWindowsXP ;StrCmp sama seperti fungsi IIF di VB

		ItIsWindowsXP:
		Goto installservice

		ItIsNotWindowsXP:
		Goto done

		installservice:
			DetailPrint "Sedang menginstall service MySQL ..."
			ExecWait '"$MySQLDir\bin\mysqld.exe" install "MySQL"'

			;jalankan service MySQL
			DetailPrint "Sedang menjalankan service MySQL ..."
			ExecWait '"$SYSDIR\net.exe" start "MySQL"'

			;mendaftarkan port default mysql (3306) ke firewall
			DetailPrint "Sedang mendaftarkan port MySQL ..."
			ExecWait '"$SYSDIR\netsh.exe" firewall add portopening TCP 3306 "Port MySQL"'

			;mengganti password default root (blank). ex : masterkey
			DetailPrint "Mengganti password root"
			ExecWait '"$MySQLDir\bin\mysqladmin.exe" -uroot password masterkey'

			;menghapus user default1 (user=blank, password=blank)
			ExecWait '"$MySQLDir\bin\mysql.exe" -uroot -pmasterkey -e "DELETE FROM mysql.user WHERE Host=$\'localhost$\' AND User=$\'$\'"'
			ExecWait '"$MySQLDir\bin\mysql.exe" -uroot -pmasterkey -e "FLUSH PRIVILEGES"'

			;menghapus user default2 (user=root, password=blank)
			ExecWait '"$MySQLDir\bin\mysql.exe" -uroot -pmasterkey -e "DELETE FROM mysql.user WHERE Host=$\'127.0.0.1$\' AND User=$\'root$\'"'
			ExecWait '"$MySQLDir\bin\mysql.exe" -uroot -pmasterkey -e "FLUSH PRIVILEGES"'

			;set agar user root bisa login dari mesin lain (kalo diperlukan)
			ExecWait '"$MySQLDir\bin\mysql.exe" -uroot -pmasterkey -e "GRANT ALL PRIVILEGES ON *.* TO root@$\'%$\' IDENTIFIED BY $\'masterkey$\'"'
			ExecWait '"$MySQLDir\bin\mysql.exe" -uroot -pmasterkey -e "FLUSH PRIVILEGES"'

		done:
			;do nothing
    SectionEnd

	Section "Install MySQL Connector ODBC"
		SetOutPath $SYSDIR

		;dll mysql odbc tidak perlu diregistrasikan
		;jadi otomatis tidak perlu memanggil fungsi RegDLL
		File "C:\Program Files\MySQL\Connector ODBC 5.1\myodbc5.dll"
		File "C:\Program Files\MySQL\Connector ODBC 5.1\myodbc5S.dll"
		File "C:\Program Files\MySQL\Connector ODBC 5.1\myodbc5.lib"
		File "C:\Program Files\MySQL\Connector ODBC 5.1\myodbc5S.lib"
		File "C:\Program Files\MySQL\Connector ODBC 5.1\myodbc-installer.exe"

		Version::IsWindowsXP

		Pop $0
		StrCmp $0 "1" ItIsWindowsXP ItIsNotWindowsXP

		ItIsWindowsXP:
		Goto installdriverodbc

		ItIsNotWindowsXP:
		Goto done

		installdriverodbc:
			;install driver myodbc
			DetailPrint "Tunggu sedang mendaftarkan driver MySQL Connector ODBC 5.1.5"
			ExecWait '"$SYSDIR\myodbc-installer.exe" -d -a -n "MySQL ODBC 5.1 Driver" -t "DRIVER=myodbc5.dll;SETUP=myodbc5S.dll"'

		done:
			;do nothing
	SectionEnd

	Section "Install Database"
		SetOutPath $MySQLDir\bin

		File "main\albasi.sql"
		File "main\exec.cmd"

		Version::IsWindowsXP

		Pop $0
		StrCmp $0 "1" ItIsWindowsXP ItIsNotWindowsXP

		ItIsWindowsXP:
		Goto installdatabase

		ItIsNotWindowsXP:
		Goto done

		installdatabase:
			;membuat database kosong
			ExecWait '"$MySQLDir\bin\mysql.exe" -uroot -pmasterkey -e "CREATE DATABASE albasi"'

			;menjalankan file batch exec.cmd untuk melakukan proses undump
			ExecWait '"$MySQLDir\bin\exec.cmd"'

		done:
			;do nothing
	SectionEnd
SectionGroupEnd

SectionGroup /e "Buat Shortcut"
	Section "Start Programs"
		SectionIn RO ;RO -> Read Only

		CreateDirectory "$SMPROGRAMS\PT. ALBASI"
		CreateShortCut "$SMPROGRAMS\PT. ALBASI\${APP_NAME}.lnk" "$MainDir\Albasi.exe" "" "$MainDir\Albasi.exe" 0
	SectionEnd

    Section "Desktop"
		;CreateDirectory "$DESKTOP\SPBB"
		CreateShortCut "$DESKTOP\${APP_NAME}.lnk" "$MainDir\Albasi.exe" "" "$MainDir\Albasi.exe" 0
	SectionEnd

	Section "Quick Launch"
		;CreateDirectory "$QUICKLAUNCH\SPBB"
		CreateShortCut "$QUICKLAUNCH\${APP_NAME}.lnk" "$MainDir\Albasi.exe" "" "$MainDir\Albasi.exe" 0
	SectionEnd
SectionGroupEnd

Section "-Registry Windows"
	;informasi uninstall
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SPBB" "DisplayName" "${APP_NAME}"
    WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SPBB" "UninstallString" '"$MainDir\uninstaller.exe"'
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SPBB" "DisplayIcon" '"$MainDir\uninstaller.exe"'

    WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SPBB" "NoModify" 1
    WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SPBB" "NoRepair" 1

    WriteUninstaller $MainDir\uninstaller.exe
SectionEnd

Section "-File Konfigurasi Program"
    WriteINIStr $MainDir\infoprogram.ini "Sistem" "serverName" "127.0.0.1"
    WriteINIStr $MainDir\infoprogram.ini "Sistem" "dbName" "albasi"
SectionEnd

Section "Uninstall"
	;stop service MySQL
	DetailPrint "Menghentikan Service MySQL ..."
	ExecWait '"$SYSDIR\net.exe" stop "MySQL"'

	;hapus service MySQL
	DetailPrint "Sedang menghapus service MySQL ..."
	ExecWait '"$MySQLDir\bin\mysqld.exe" remove "MySQL"'

	;driver MySQL Connector ODBC 5.1
	DetailPrint "Tunggu sedang menghapus driver MySQL Connector ODBC 5.1"
	ExecWait '"$SYSDIR\myodbc-installer.exe" -d -r -n "MySQL ODBC 5.1 Driver"'

	; Remove registry keys
	DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SPBB"

	; Remove files and uninstaller
	Delete $MainDir\*.*
	RMDir $MainDir

	; Remove shortcuts
	Delete "$SMPROGRAMS\PT. ALBASI\*.*"
	RMDir "$SMPROGRAMS\PT. ALBASI"

	Delete "$DESKTOP\${APP_NAME}.lnk"
	Delete "$QUICKLAUNCH\${APP_NAME}.lnk"
SectionEnd

;fungsi untuk menampilkan gambar/banner pada saat instalasi
;untuk contoh disini posisi gambar di sebelah kiri
Function BrandingImage
	SetOutPath "$TEMP"

	SetFileAttributes SetupModern21.bmp temporary
	File SetupModern21.bmp
	SetBrandingImage "$TEMP\SetupModern21.bmp" /resizetofit
FunctionEnd

;fungsi untuk menampilkan gambar/banner pada saat uninstall
Function un.BrandingImage
	SetBrandingImage "$TEMP\SetupModern21.bmp" /resizetofit
FunctionEnd

Di dalam skrip instalasi ada file exec.cmd, isinya adalah :

mysql -uroot -pmasterkey albasi < albasi.sql

Isi file exec.cmd sebenarnya untuk proses undump dan ternyata Inno Setup dan NSIS gagal menjalankan perintah tersebut, padahal perintah-perintah yang lainnya sukses.

Contoh hasil instalasi :

Selamat mencoba :blush:

Comments